Константы графиков

Константы, описывающие различные свойства графиков, разделены на следующие группы:

• Типы событий – события, которые возникают при работе с графиком;
• Периоды графиков – стандартные встроенные периоды;
• Свойства графиков – идентификаторы, используемые в качестве параметров функций для работы с графиками;
• Константы позиционирования — значения параметра функции ChartNavigate();
• Отображение графиков — задание внешнего вида графика.

 

Типы событий графика

Существуют 11 видов событий, которые можно обрабатывать с помощью функции предопределенной функции OnChartEvent(). Для пользовательских событий предусмотрено 65535 идентификаторов в диапазоне от CHARTEVENT_CUSTOM до CHARTEVENT_CUSTOM_LAST включительно. Для генерации пользовательского события необходимо использовать функцию EventChartCustom().

ENUM_CHART_EVENT

Для каждого типа события входные параметры функции OnChartEvent() имеют определенные значения, которые необходимы для обработки этого события. В таблице перечислены события и значения, которые передаются через параметры.

Пример:

#define KEY_NUMPAD_5 12 
#define KEY_LEFT 37 
#define KEY_UP 38 
#define KEY_RIGHT 39 
#define KEY_DOWN 40 
#define KEY_NUMLOCK_DOWN 98 
#define KEY_NUMLOCK_LEFT 100 
#define KEY_NUMLOCK_5 101 
#define KEY_NUMLOCK_RIGHT 102 
#define KEY_NUMLOCK_UP 104 
//+------------------------------------------------------------------+ 
//| Expert initialization function | 
//+------------------------------------------------------------------+ 
int OnInit() 
{
 //--- 
 Print("Запущен эксперт с именем ",MQL5InfoString(MQL5_PROGRAM_NAME));
 //--- установка флага получения событий создания объектов графика 
 ChartSetInteger(ChartID(),CHART_EVENT_OBJECT_CREATE,true); 
 //--- установка флага получения событий удаления объектов графика 
 ChartSetInteger(ChartID(),CHART_EVENT_OBJECT_DELETE,true);
//--- 
 return(INIT_SUCCEEDED); 
}
//+------------------------------------------------------------------+ 
//| ChartEvent function | 
//+------------------------------------------------------------------+ 
void OnChartEvent(const int id, 
                  // идентификатор события 
                  const long& lparam, // параметр события типа long 
                  const double& dparam, // параметр события типа double 
                  const string& sparam // параметр события типа string) 
{ 
                  //--- нажатие левой кнопкой мышки на графике 
 if(id==CHARTEVENT_CLICK) 
 {
    Print("Координаты щелчка мышки на графике: x = ",lparam," y = ",dparam); 
 }

 //--- нажатие мышкой на графическом объекте 
 if(id==CHARTEVENT_OBJECT_CLICK) 
 {
    Print("Нажатие кнопки мышки на объекте с именем '"+sparam+"'"); 
 }

 //--- нажатие кнопки на клавиатуре 
 if(id==CHARTEVENT_KEYDOWN) 
 {
    switch(lparam) 
    {
        case KEY_NUMLOCK_LEFT: Print("Нажата KEY_NUMLOCK_LEFT"); break;
        case KEY_LEFT: Print("Нажата KEY_LEFT"); break;
        case KEY_NUMLOCK_UP: Print("Нажата KEY_NUMLOCK_UP"); break;
        case KEY_UP: Print("Нажата KEY_UP"); break;
        case KEY_NUMLOCK_RIGHT: Print("Нажата KEY_NUMLOCK_RIGHT"); break;
        case KEY_RIGHT: Print("Нажата KEY_RIGHT"); break;
        case KEY_NUMLOCK_DOWN: Print("Нажата KEY_NUMLOCK_DOWN"); break;
        case KEY_DOWN: Print("Нажата KEY_DOWN"); break;
        case KEY_NUMPAD_5: Print("Нажата KEY_NUMPAD_5"); break;
        case KEY_NUMLOCK_5: Print("Нажата KEY_NUMLOCK_5"); break;
        default: Print("Нажата какая-то неперечисленная клавиша"); 
    }
    ChartRedraw(); 
 }

 //--- удален объекта 
 if(id==CHARTEVENT_OBJECT_DELETE)
 {
    Print("Удален объект с именем ",sparam); 
 }

 //--- создан объект 
 if(id==CHARTEVENT_OBJECT_CREATE) 
 {
    Print("Создан объект с именем ",sparam); 
 }

 //--- перемещен объект или изменены координаты точек привязки 
 if(id==CHARTEVENT_OBJECT_DRAG) 
 {
    Print("Изменение точек привязки объекта с именем ",sparam); 
 }

 //--- изменен текст в поле ввода графического объекта Edit 
 if(id==CHARTEVENT_OBJECT_ENDEDIT) 
 {
    Print("Изменен текст в объекте Edit ",sparam); 
 } 
}

 

Для события CHARTEVENT_MOUSE_MOVE строковой параметр sparam содержит число, представляющее информацию о состоянии клавиш:

Пример:

//+------------------------------------------------------------------+
//| Expert initialization function |
//+------------------------------------------------------------------+
void OnInit()
{
   //--- включение сообщений о перемещении мыши по окну чарта
   ChartSetInteger(0,CHART_EVENT_MOUSE_MOVE,1);
}

//+------------------------------------------------------------------+
//| MouseState |
//+------------------------------------------------------------------+
string MouseState(uint state)
{
   string res;
   res+="\nML: " +(((state& 1)== 1)?"DN":"UP"); // mouse left
   res+="\nMR: " +(((state& 2)== 2)?"DN":"UP"); // mouse right 
   res+="\nMM: " +(((state&16)==16)?"DN":"UP"); // mouse middle
   res+="\nMX: " +(((state&32)==32)?"DN":"UP"); // mouse first X key
   res+="\nMY: " +(((state&64)==64)?"DN":"UP"); // mouse second X key
   res+="\nSHIFT: "+(((state& 4)== 4)?"DN":"UP"); // shift key
   res+="\nCTRL: " +(((state& 8)== 8)?"DN":"UP"); // control key
   return(res);
}

//+------------------------------------------------------------------+
//| ChartEvent function |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,const long &lparam,const double &dparam,const string &sparam)
{
   if(id==CHARTEVENT_MOUSE_MOVE)
     Comment("POINT: ",(int)lparam,",",(int)dparam,"\n",MouseState((uint)sparam));
}

Для события CHARTEVENT_MOUSE_WHEEL параметры lparam и dparam содержат информацию о состоянии клавиш Ctrl, Shift, кнопок мышки, координатах курсора и величине прокрутки колёсика мышки. Для лучшего понимания запустите этот советник на графике и прокручивайте колёсико мышки, нажимая поочередно различные кнопки и клавиши, описанные в коде.

Пример обработки события CHARTEVENT_MOUSE_WHEEL:

//+------------------------------------------------------------------+
//| Expert initialization function |
//+------------------------------------------------------------------+
void OnInit()
{
   //--- включение сообщений о прокрутке колесика мышки
   ChartSetInteger(0,CHART_EVENT_MOUSE_WHEEL,1);
   return(INIT_SUCCEEDED);
}

//+------------------------------------------------------------------+
//| ChartEvent function |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,const long &lparam,const double &dparam,const string &sparam)
{
   if(id==CHARTEVENT_MOUSE_WHEEL)
   {
      //--- разберем состояние кнопок и колесика мышки для этого события 
      int flg_keys = (int)(lparam>>32); // флаг состояний клавиш Ctrl, Shift и кнопок мышки
      int x_cursor = (int)(short)lparam; // X-координата, в которой произошло событие колесика мышки
      int y_cursor = (int)(short)(lparam>>16); // Y-координата, в которой произошло событие колесика мышки
      int delta = (int)dparam; // суммарное значение прокрутки колесика, срабатывает при достижении +120 или -120

      //--- обработаем флаг 
      string str_keys="";
      if((flg_keys&0x0001)!=0) str_keys+="LMOUSE ";
      if((flg_keys&0x0002)!=0) str_keys+="RMOUSE ";
      if((flg_keys&0x0004)!=0) str_keys+="SHIFT ";
      if((flg_keys&0x0008)!=0) str_keys+="CTRL ";
      if((flg_keys&0x0010)!=0) str_keys+="MMOUSE ";
      if((flg_keys&0x0020)!=0) str_keys+="X1MOUSE ";
      if((flg_keys&0x0040)!=0) str_keys+="X2MOUSE ";
 
      if(str_keys!="")
        str_keys=", keys='"+StringSubstr(str_keys,0,StringLen(str_keys)-1) + "'";

      PrintFormat("%s: X=%d, Y=%d, delta=%d%s",EnumToString(CHARTEVENT_MOUSE_WHEEL),x_cursor,y_cursor,delta,str_keys);
 }
 }

//+------------------------------------------------------------------+ /*
 Пример вывода
 CHARTEVENT_MOUSE_WHEEL: Ctrl pressed: X=193, Y=445, delta=-120
 CHARTEVENT_MOUSE_WHEEL: Shift pressed: X=186, Y=446, delta=120
 CHARTEVENT_MOUSE_WHEEL: X=178, Y=447, delta=-120
 CHARTEVENT_MOUSE_WHEEL: X=231, Y=449, delta=120
 CHARTEVENT_MOUSE_WHEEL: MiddleButton pressed: X=231, Y=449, delta=120
 CHARTEVENT_MOUSE_WHEEL: LeftButton pressed: X=279, Y=320, delta=-120
 CHARTEVENT_MOUSE_WHEEL: RightButton pressed: X=253, Y=330, delta=120 */

 

Периоды графиков

Все предопределенные периоды графиков имеют уникальные идентификаторы. Идентификатор PERIOD_CURRENT означает текущий период графика, на котором запущена mql5-программа.

ENUM_TIMEFRAMES

Пример:

 string chart_name="test_Object_Chart";
 Print("Попробуем создать объект Chart с именем ",chart_name);

//--- если такого объекта нет - создадим его
 if(ObjectFind(0,chart_name)<0)
    ObjectCreate(0,chart_name,OBJ_CHART,0,0,0,0,0);

//--- зададим символ
 ObjectSetString(0,chart_name,OBJPROP_SYMBOL,"EURUSD");

//--- зададим координату X для точки привязки
 ObjectSetInteger(0,chart_name,OBJPROP_XDISTANCE,100);

//--- зададим координату Y для точки привязки
 ObjectSetInteger(0,chart_name,OBJPROP_YDISTANCE,100);

//--- установим ширину
 ObjectSetInteger(0,chart_name,OBJPROP_XSIZE,400);

//--- установим высоту
 ObjectSetInteger(0,chart_name,OBJPROP_YSIZE,300);

//--- установим период
 ObjectSetInteger(0,chart_name,OBJPROP_PERIOD,PERIOD_D1);

//--- установим масшаб ( от 0 до 5)
 ObjectSetDouble(0,chart_name,OBJPROP_SCALE,4);

//--- сделаем недоступным для выделения мышкой 
 ObjectSetInteger(0,chart_name,OBJPROP_SELECTABLE,false);

 

Свойства графиков

Идентификаторы семейства перечислений ENUM_CHART_PROPERTY используются в качестве параметров функций для работы с графиками. Аббревиатура r/o в столбце «Тип свойства» означает, что данное свойство предназначено только для чтения и не может быть изменено. Аббревиатура w/o в столбце «Тип свойства» означает, что данное свойство предназначено только для записи и не может быть получено. При обращении к некоторым свойствам необходимо указывать дополнительный параметр-модификатор (modifier), который служит для указания номера подокна графика. 0 означает главное окно.

Функции, устанавливающие свойства графика, фактически служат для отправки ему команд на изменение. При успешном выполнении этих функций команда попадает в общую очередь событий графика. Изменение графика производится в процессе обработки очереди событий данного графика.

По этой причине не следует ожидать немедленного визуального обновления графика после вызова данных функций. В общем случае обновление графика производится терминалом автоматически по событиям изменения — поступление новой котировки, изменения размера окна графика и т.д. Для принудительного обновления внешнего вида графика используйте команду на перерисовку графика ChartRedraw().

Для функций ChartSetInteger() и ChartGetInteger()

ENUM_CHART_PROPERTY_INTEGER

Для функций ChartSetDouble() и ChartGetDouble()

ENUM_CHART_PROPERTY_DOUBLE

Для функций ChartSetString() и ChartGetString()

ENUM_CHART_PROPERTY_STRING

Пример:

 int chartMode=ChartGetInteger(0,CHART_MODE);
 switch(chartMode)
 {
    case(CHART_BARS): Print("CHART_BARS"); break;
    case(CHART_CANDLES): Print("CHART_CANDLES");break;
    default:Print("CHART_LINE");
 }

 bool shifted=ChartGetInteger(0,CHART_SHIFT);

 if(shifted) Print("CHART_SHIFT = true");
   else Print("CHART_SHIFT = false");

 bool autoscroll=ChartGetInteger(0,CHART_AUTOSCROLL);

 if(autoscroll) Print("CHART_AUTOSCROLL = true");
    else Print("CHART_AUTOSCROLL = false");

 int chartHandle=ChartGetInteger(0,CHART_WINDOW_HANDLE);
 Print("CHART_WINDOW_HANDLE = ",chartHandle);
 int windows=ChartGetInteger(0,CHART_WINDOWS_TOTAL);
 Print("CHART_WINDOWS_TOTAL = ",windows);
 if(windows>1)
 {
    for(int i=0;i<windows;i++)
    {
       int height=ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,i);
       double priceMin=ChartGetDouble(0,CHART_PRICE_MIN,i);
       double priceMax=ChartGetDouble(0,CHART_PRICE_MAX,i);
       Print(i+": CHART_HEIGHT_IN_PIXELS = ",height,"pixels");
       Print(i+": CHART_PRICE_MIN = ",priceMin);
       Print(i+": CHART_PRICE_MAX = ",priceMax);
    }
 }

Позиционирование графика

Три идентификатора из списка ENUM_CHART_POSITION являются возможными значениями параметра position для функции ChartNavigate().

ENUM_CHART_POSITION

Пример:

 long handle=ChartOpen("EURUSD",PERIOD_H12);
 if(handle!=0)
 {
    ChartSetInteger(handle,CHART_AUTOSCROLL,false);
    ChartSetInteger(handle,CHART_SHIFT,true);
    ChartSetInteger(handle,CHART_MODE,CHART_LINE);
    ResetLastError();

    bool res=ChartNavigate(handle,CHART_END,150);

    if(!res)
      Print("Navigate failed. Error = ",GetLastError());
    ChartRedraw();
 }

Отображение графиков

Ценовые графики можно отображать тремя способами:

• в виде баров;
• в виде свечей;
• в виде ломаной линии.

Конкретный способ отображения ценового графика задается функцией ChartSetInteger(handle_графика,CHART_MODE, тип_графика), где тип_графика – одно из значений перечисления ENUM_CHART_MODE.

ENUM_CHART_MODE

Для указания режима отображения объемов на ценовом графике используется функция ChartSetInteger(handle_графика, CHART_SHOW_VOLUMES, тип_отображения), где тип_отображения – одно из значений перечисления ENUM_CHART_VOLUME_MODE.

ENUM_CHART_VOLUME_MODE

Пример:

//--- получим handle текущего графика
 long handle=ChartID();
 if(handle>0) // если получилось, дополнительно настроим
 {
    //--- отключим автопрокрутку
    ChartSetInteger(handle,CHART_AUTOSCROLL,false);

    //--- установим отступ правого края графика
    ChartSetInteger(handle,CHART_SHIFT,true);

    //--- отобразим в виде свечей
    ChartSetInteger(handle,CHART_MODE,CHART_CANDLES);

    //--- прокрутим на 100 баров от начала истории
    ChartNavigate(handle,CHART_CURRENT_POS,100);

    //--- установить режим отображения тиковых объемов
    ChartSetInteger(handle,CHART_SHOW_VOLUMES,CHART_VOLUME_TICK);
 }